«Where did I leave my keys?» by julian.rohrhuber

on 01 Nov'13 23:05 in speculativemultichannelcrossing

Cross-tuning between multiple signal dimensions. The code is finished without listening.

log fork json 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
// where did I leave my keys?
(
var n = 30, m = 5;
Ndef.clear(3);
Ndef.ar(\x, n);
Ndef(\y, { Splay.ar(Ndef.ar(\x, m, LFNoise1.kr(1/m).range(0, n - m - 1))).clip2 * 0.5 }).play; 
Ndef(\x, { 
	{ 
		var a = Ndef.ar(\x, 1, LFNoise0.kr(Rand()) * Rand() + Rand() * n);
		a + 0.1 * SinOsc.ar(ExpRand(0.2, 1000)) 
	} ! n
}); 
)

// where did I put my keys?
(
var n = 30, m = 5;
Ndef.clear(3);
Ndef.ar(\x, n);
Ndef(\y, { Splay.ar(Ndef.ar(\x, m, LFNoise1.kr(1/m).range(0, n - m - 1))).clip2 * 0.5 }).play; 
Ndef(\x, { 
	{
		var a = Ndef.ar(\x, 1, LFNoise0.kr(Rand()) * Rand() + Rand() * n);
		SinOsc.ar(ExpRand(0.2, 1000), a) 
	} ! n
}); 
)
raw 656 chars (focus & ctrl+a+c to copy)
reception
comments
rukano ↪ user 04 Nov'13 15:01

where did I left my ears? They were blown by the headphones... ;)

julian.rohrhuber ↪ user 10 Nov'13 20:30

Sorry, didn't sound lik ethis when I last tried - will try to fix!

julian.rohrhuber ↪ user 10 Nov'13 20:34

Ok, should be better now :)

fbfrankb5 ↪ user 04 Nov'24 08:24

This is so good