«playing around with ComplexRes UGen» by julian.rohrhuber

on 16 Mar'14 17:33 in subtractive synthesis
log fork json 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
(
z = { exprand(100.0, 5000.0) } ! 20;
Ndef(\x, {
	var in = Decay.ar(Dust.ar(MouseX.kr(0.0001, 0.1, 1) * z, 10), 0.3) * PinkNoise.ar(0.4 ! (z.size div: 3), 1);
	z = z * LFNoise1.ar(0.2 ! z.size).range(1, 2) * LFNoise0.ar(20 ! z.size).exprange(1, 1.8);
	Splay.ar(ComplexRes.ar(in, z, 10 / z)) * 2
}).play
)


// this started out as a comparison between BPF and ComplexRes


(
z = [253.12, 2881.123, 2883.4, 1002.2, 882.01];
Ndef(\x, {
	var in = Decay.ar(Dust.ar(5, 100), 0.3) * PinkNoise.ar(0.4, 1);
	ComplexRes.ar(in, z, 10 / z).sum
}).play
)


(
z = [253.12, 2881.123, 2883.4, 1002.2, 882.01];
Ndef(\x, {
	var in = Decay.ar(Dust.ar(5, 100), 0.3) * PinkNoise.ar(0.4, 1);
	BPF.ar(in, z, (10 / z) * 2).sum
}).play
)

(
z = [253.12, 2881.123, 2883.4, 1002.2, 882.01];
Ndef(\x, {
	var in = Decay.ar(Dust.ar(5, 100), 0.3) * PinkNoise.ar(0.4, 1);
	z = z * LFNoise0.ar(13).range(1, 2);
	ComplexRes.ar(in, z, 10 / z).sum
}).play
)


(
z = [253.12, 2881.123, 2883.4, 1002.2, 882.01];
Ndef(\x, {
	var in = Decay.ar(Dust.ar(5, 100), 0.3) * PinkNoise.ar(0.4, 1);
	z = z * LFNoise0.ar(13).range(1, 2);
	BPF.ar(in, z, (10 / z) * 2).sum
}).play
)
descendants
«Re: playing around with ComplexRes UGen» by julian.rohrhuber (private)
full graph
raw 1178 chars (focus & ctrl+a+c to copy)
reception
comments
LFSaw ↪ user 26 Mar'14 16:53

The interesting part of ComplexRes is that all its parameters can be modulated in audiorate without blowing up. So it is possible to create nice FM-like structures...