«strange place» by vividsnow

on 20 Sep'11 13:56 in scifisketchexperimental

Just experimental sketch of somewhere audio background.

p.s. some random variations on each run.

log fork json 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
(
{ 
	Limiter.ar(
		GVerb.ar(
			(	
				BPF.ar(
					WhiteNoise.ar([0.07,0.07]) + Blip.ar([13,19], 200.rand, mul:0.5),
					SinOsc.kr(
						SinOsc.kr([1/108,1/109]).range(1/108, 1/13)
					).exprange(10, 23000),
					PMOsc.kr(1/54,1/216, 3).range(0.1, 2)
				) 
				* 
				SinOsc.ar(Array.rand(20, 1/216, 1), mul: Array.rand(20, 0.2, 1)).reshape(10,2)
			).sum,
			roomsize:10,
			damping: PMOsc.kr(1/27, 1/108, 3).range(0.5, 1), 
			drylevel: SinOsc.kr(1/9).range(0.1, 1)
		)
		+
		GVerb.ar(
			Pan2.ar(
				LPF.ar(
					DynKlank.ar(
						`[
							Array.rand(6, 600, 4000).collect({|freq|
								SinOsc.kr(1/108).range(freq/2,freq)
							}), 
							nil, 
							Array.rand(6, 1/108, 1/27).collect({|freq|
								SinOsc.kr(freq).range(1/108,1/3)
							})
						],
						Limiter.ar(
							Dust.ar( SinOsc.kr(1/256).exprange(1/27, 3), TRand.kr(0.15, 0.25, Dust.kr(1/9))) 
							+ 
							Impulse.ar( SinOsc.kr(1/108).exprange(1/54, 3), 0, TRand.kr(0.6, 0.8, Dust.kr(1/3)))
						)
					),
					1700,
					LFPar.kr(1/27).exprange(0.05, 0.2)
				),
				SinOsc.kr(1/9).range(-0.2, 0.2)
			),
			roomsize: 30,
			drylevel: 0.5
		)
	)
}.play;
)
full graph
raw 1196 chars (focus & ctrl+a+c to copy)
reception
comments
freejazztampa ↪ user 21 Oct'11 07:36

Bravo! I'd love to know how you thought up the "sequencing of this". I don't think I could make something so elaborate without patterns.

vividsnow ↪ user 21 Oct'11 22:27

Thank you! This is just result of experimental flow from scratch without initial idea of what I'm going to do and with intention to understand some unexplored SC functionality (e.g. UGens)

axiomshell ↪ user 27 Oct'11 23:43

Great. Now I'm lost in a strange space.

(Which is amazing)

whillas ↪ user 18 Jun'12 08:17

pops my sound card every time. I don't know how that is possible with the Limiter???

vividsnow ↪ user 18 Jun'12 15:00

maybe it is not sound card, but overload of cpu

nufets ↪ user 18 Jun'12 19:24

GVerb has it's pecularities (though i don't believe it's necessarily only related to that...)

p.dupuis ↪ user 06 Feb'18 04:00

The problem is on line 10: exprange(10, 23000). Should be 2300, not 23000!

g_montel ↪ user 03 Apr'18 18:50

impressive