«Dub Echo» by Bjorn Westergard

on 09 Aug'11 21:55 in dubechospacechofeedback

A pretty simple Dub echo, approximating something like the Space Echo made popular by King Tubby, Scientist, Lee Perry, et al. Built around the Feedback Quark, though I'm not really leaning on the functionality it provides over a simple LocalOut-based feedback path.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
SynthDef(\dubecho,{|length = 1, fb = 0.8, sep = 0.012|
var input = In.ar(0, 2);
var output = input + Fb({

arg feedback; // this will contain the delayed output from the Fb unit

var left,right;
var magic = LeakDC.ar(feedback*fb + input);
magic = HPF.ar(magic, 400); // filter's on the feedback path
magic = LPF.ar(magic, 5000);
magic = magic.tanh; // and some more non-linearity in the form of distortion
#left, right = magic; // let's have named variables for the left and right channels
magic = [DelayC.ar(left, 1, LFNoise2.ar(12).range(0,sep)), DelayC.ar(right, 1, LFNoise2.ar(12).range(sep,0))]; // In addition to the main delay handled by the feedback quark, this adds separately modulated delays to the left and right channels, which with a small "sep" value creates a bit of spatialization

},length);
ReplaceOut.ar(0, output);
}).store;

// Example Usage
~echo = Synth(\dubecho, [\length, TempoClock.default.tempo*(3/8), \fb, 0.7, \sep, 0.0012], addAction: \addToTail);
~echo.free;
~echo.set(\gate, 0);
raw 1032 chars (focus & ctrl+a+c to copy)
reception
comments
rukano user 15 Aug'11 20:17

Maybe you should warn that one needs the Feedback Quark to run?

Bjorn Westergard user 16 Aug'11 00:44

Mentioned it in the description, so... consider yourself warned? :-)

rukano user 16 Aug'11 02:21

oh! sorry... just read the synth ^_^ my fault. /* personal note: read descriptions */