«Re: Dub Echo using LocalIn + LocalOut (and Ping Pong)» by rukano

on 22 Feb'12 07:41 in dubechospacechofeedbackcode fork

Fork of Bjorn's Dub echo, rewritten w/o the Feedback Quark (using LocalIn + LocalOut) and adding a ping pong (can be removed by deleting the .reverse method in the LocalOut line)

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
SynthDef(\dubecho,{|in, out, length = 1, fb = 0.8, sep = 0.012|
	var input = In.ar(in, 2);
	var feedback = LocalIn.ar(2);
	var output = LeakDC.ar(feedback*fb + input);
	output = HPF.ar(output, 400);
	output = LPF.ar(output, 5000);
	output = output.tanh;
	LocalOut.ar(DelayC.ar(output, 1, LFNoise2.ar(12).range([length,length+sep],[length+sep,length])).reverse);
	ReplaceOut.ar(out, output);
}).add;

// Example as effecet bus
~bus = Bus.audio(s, 2);
~echo = Synth(\dubecho, [\in, ~bus, \length, TempoClock.default.tempo*(3/8), \fb, 0.7, \sep, 0.0012], addAction: \addToTail);

// send something
play{ Out.ar(~bus, LFGauss.ar(1, 0.1, loop:0, doneAction:2) * Blip.ar(80!2, 8)) }

// turn it off
~echo.free;
raw 723 chars (focus & ctrl+a+c to copy)
reception
comments