«Re: Dub Echo with Ping Pong» by rukano

on 22 Feb'12 05:18 in dubechospacechofeedbackcode fork

Taking the Dub echo by Bjorn and putting some ping poing to it :)

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
SynthDef(\dubecho,{|in, out, length = 1, fb = 0.8, sep = 0.012|
	var input = In.ar(in, 2);
	var output = input + Fb({ |feedback|
		
		var left, right;
		var magic = LeakDC.ar(feedback*fb + input);
		magic = HPF.ar(magic, 400); // filter's on the feedback path
		magic = LPF.ar(magic, 5000);
		magic = magic.tanh; // and some more non-linearity in the form of distortion
		#left, right = magic; // let's have named variables for the left and right channels
		magic = [DelayC.ar(left, 1, LFNoise2.ar(12).range(0,sep)), DelayC.ar(right, 1, LFNoise2.ar(12).range(sep,0))].reverse;

	},length);

	ReplaceOut.ar(out, output);
}).add;

// Example as effecet bus
~bus = Bus.audio(s, 2);
~echo = Synth(\dubecho, [\in, ~bus, \length, TempoClock.default.tempo*(3/8), \fb, 0.7, \sep, 0.0012], addAction: \addToTail);

// send something
play{ Out.ar(~bus, LFGauss.ar(1, 0.1, loop:0, doneAction:2) * Blip.ar(80, 8)) }

// turn it off
~echo.free;
raw 956 chars (focus & ctrl+a+c to copy)
reception
comments
triss user 11 Apr'12 12:27

where do I find the Fb class?

robertol80 user 11 Apr'12 17:06

download the Feedback Quark