«Rain and thunder» by Jonatan Liljedahl

on 09 Aug'11 20:34 in rainthundernaturesoundeffects

I tried to help a friends friend to find some suitable recording of rain and thunder on the net, but I ended up coding this up for him instead, and he was happy.

code
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
(
play {
    Limiter.ar(
        tanh(
            3 * GVerb.ar(
                HPF.ar(
                    PinkNoise.ar(0.08+LFNoise1.kr(0.3,0.02))+LPF.ar(Dust2.ar(LFNoise1.kr(0.2).range(40,50)),7000),
                    400
                ),
                250,100,0.25,drylevel:0.3
            ) * Line.kr(0,1,10)
        ) + (
            GVerb.ar(
                LPF.ar(
                    10 * HPF.ar(PinkNoise.ar(LFNoise1.kr(3).clip(0,1)*LFNoise1.kr(2).clip(0,1) ** 1.8), 20)
                    ,LFNoise1.kr(1).exprange(100,2500)
                ).tanh,
               270,30,0.7,drylevel:0.5
            ) * Line.kr(0,0.7,30)
        )
    )
};
)
descendants
«Ival» by anonymous (private)
«ppggafr» by anonymous (private)
«liindu» by anonymous (private)
full graph
raw 683 chars (focus & ctrl+a+c to copy)
reception
comments
vividsnow user 09 Aug'11 20:49

it works well - want to sleep like when natural rain occurs )

Jonatan Liljedahl user 09 Aug'11 20:55

thanks. I had some real rain and thunder here earlier today, for reference :) I'd like to have some occasional loud thunder bangs too, and the phasing-effects sometimes heard in close thunder..

Schemawound user 09 Aug'11 20:55

Fantastic!

Bjorn Westergard user 10 Aug'11 02:18

Believable.

Roberto Lombardo user 10 Aug'11 11:05

Good work ... I can feel the rain on my skin ( :P ).

rukano user 10 Aug'11 15:02

For a moment there I though it was raining! Oh... it's raining! :)

38nonprivate user 12 Aug'11 13:35

really great - however here in berlin we have no need for such a synthdef as we get to hear these sounds for free on a regular basis during the "summer."

beryann.parker user 18 Nov'11 13:07

Excellent!!I knew this one from N.Virgo (try to mix the 2 one with panning....:>) Beryann!!

play{p=PinkNoise.ar(1!2);BRF.ar(p+Blip.ar(p+2,400),150,2,0.1)+LPF.ar(FreeVerb2.ar(LPF.ar(p+0.2Dust.ar(0.1),60)++[1,1,0.2,1e4]).tanh,2000)}