«sine ocean» by eli.fieldsteel

on 23 Apr'14 20:01 in sinepatternsrandomspatializationmetalpureimmersive

150 unique streams of harmonic sine waves ebb and flow, gradually drifting more and more out of phase

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
(
//fundamental pitch triad
~notes = [45,55,60].midicps;

s.waitForBoot({
	Routine{

		SynthDef.new(\tone, {
			arg freq=440, pan=0, rel=0.05;
			var sig;
			sig = SinOsc.ar(freq);
			sig = sig * EnvGen.kr(Env.perc(0.005,rel), doneAction:2);
			sig = Pan2.ar(sig, pan, 0.05);
			Out.ar(0, sig);
		}).add;

		s.sync;

		50.do{
			Pbind(
				\instrument, \tone,

				//trace some event times just for fun
				\dur, Pseq(Array.geom(50, rrand(1.5,1.51), rrand(0.923,0.929)).mirror,inf).trace,

				\freq, exprand(~notes[0],8000).round(~notes[0]),
				\pan, rrand(-1.0,1.0),
				\rel, exprand(0.005,0.35),
			).play;

			Pbind(
				\instrument, \tone,
				\dur, Pseq(Array.geom(50, rrand(1.5,1.51), rrand(0.923,0.929)).mirror,inf),
				\freq, exprand(~notes[1],11000).round(~notes[1]),
				\pan, rrand(-1.0,1.0),
				\rel, exprand(0.005,0.35),
			).play;

			Pbind(
				\instrument, \tone,
				\dur, Pseq(
					Array.geom(50, rrand(1.5,1.51), rrand(0.923,0.929)).mirror,inf
				),
				\freq, exprand(~notes[2],15000).round(~notes[2]),
				\pan, rrand(-1.0,1.0),
				\rel, exprand(0.005,0.35),
			).play;
		};
	}.play(AppClock);
});
)
raw 1178 chars (focus & ctrl+a+c to copy)
reception
comments