«Feedback with beats» by rukano

on 10 Aug'11 17:12 in feedbackbeat

Trying out some stuff to get some melodies/pads out of feedback and some beats in the background.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Ndef(\a, {
	var src, loc, delay=0.01;
	src = Decay2.ar(Impulse.ar(1/8), LFNoise2.kr(4).range(0.001, 0.0001),
	LFNoise2.kr(4).range(0.005, 0.05))!2
	* Saw.ar(LFNoise2.kr(4).exprange(40, 4000));
	loc = BPF.ar(LocalIn.ar(2) + [src, 0], LFNoise0.kr(1/4).range(100, 1200).lag, 3.2);
	loc = GVerb.ar(loc, 100, 4, mul:0.02, add:loc);
	loc = Compander.ar(loc, loc, 0.9, 1, 0.001);
	loc = (loc * 0.501).tanh;
	loc = Compander.ar(loc, loc, 0.1, 1, 0.1);	
	loc = DelayC.ar(loc, delay * 2, delay * 1);
	LocalOut.ar(loc.reverse * 0.49);
	Out.ar(0, loc * 0.9)
}).play;

Ndef(\b, {
	var src, loc, del;
	del = 1/100;
	src = Decay2.ar(TDuty.ar(1/4,0,Dseq([1, 0.5, 0.3, 0.1],inf)), 
	LFNoise2.kr(4).range(0.001, 0.0001), LFNoise2.kr(4).range(0.005, 0.05))!2
	* Saw.ar(LFNoise2.kr(200).exprange(40, 14000));
	loc = BPF.ar(LocalIn.ar(2) + [src, 0], LFNoise2.kr(0.1).range(40, 400), 3.2);
	loc = GVerb.ar(loc, 100, 4, mul:0.02, add:loc);
	loc = Compander.ar(loc, loc, 0.9, 1, 0.001);
	loc = (loc * 0.51).tanh;
	loc = Compander.ar(loc, loc, 0.1, 1, 0.1);	
	loc = DelayC.ar(loc, del * 2, del * 1);
	LocalOut.ar(loc.reverse * 0.45);
	Out.ar(0, Compander.ar(loc,loc,0.1, 1, 0.05) * 1.2)
}).play;

Ndef(\c, {
	var src, loc, del=1/4;
	src = Decay2.ar(Impulse.ar(1), 0.0001, 0.05) * SinOsc.ar(60);
	loc = src + LocalIn.ar(2);
	loc = BPF.ar(loc, 800, 3.2).softclip;
	loc = DelayN.ar(loc, del, [0, del]);
	LocalOut.ar(loc.reverse * 0.99);
	Out.ar(0, loc * 2)
}).play;
descendants
«Re: Feedback with beats» by Don Smith (private)
full graph
raw 1476 chars (focus & ctrl+a+c to copy)
reception
comments
all n4tural user 15 Aug'11 21:33

cool, i listened for half an hour while reading. sometimes it seemed like a and b were influencing each other. (you have to believe in magic)

nuss user 15 Aug'11 23:37

strange, this plays for a while and then suddenly ... no more sound (just wondering how you can listen to it for half an hour ...)

nuss user 15 Aug'11 23:56

... sorry, don't get me wrong. i didn't want to seem impolite ... this is happening on macintel (core duo) os 10.6.8, 64bit (os + sc)

rukano user 16 Aug'11 00:59

Hm, it works for me also indefinitely. Are you using a custom SC or official stable release? I wrote this on 3.4.4 and works for long periods of time... Sorry it won't work for you... Maybe some weird magic happening in the feedback on your machine...? No idea... :(

nuss user 16 Aug'11 01:16

well, sc 3.5~dev version ...

rukano user 16 Aug'11 01:29

If you can try it on 3.4.4 and we figure out what isn't working, we might report as bug or so...?

Bjorn Westergard user 16 Aug'11 06:48

Sounds like a palm-muted guitar string. "b" is particularly intense.

One of my favorites posted here so far.