«instant nostalgia with wow and flutter» by 56228375

on 31 Aug'19 09:22 in effectwowflutternostalgia

add instant nostalgia to your music with a touch of wow and flutter link for the sample: https://drive.google.com/file/d/1qysrKqJ0S6Huub4mEKp2Gk8FJqq-gK1C/view?usp=sharing (probably not a physically accurate emulation)

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
// read a soundfile
(
s.waitForBoot({

    SynthDef(\wowflutter_2chan, {
        arg bufnum, out = 0, wobble_rpm=33, wobble_amp=0.05, wobble_exp=39, flutter_amp=0.03, flutter_fixedfreq=6, flutter_variationfreq=2;
        var signed_wobble = wobble_amp*(SinOsc.kr(wobble_rpm/60)**wobble_exp);
        var wow = Select.kr(signed_wobble > 0, signed_wobble, 0);
        var flutter = flutter_amp*SinOsc.kr(flutter_fixedfreq+LFNoise2.kr(flutter_variationfreq));
        var combined_defects = 1 + wow + flutter;
        var sig = PlayBuf.ar(2, bufnum, BufRateScale.kr(bufnum)*combined_defects, doneAction:Done.freeSelf);
        Out.ar(out, sig);
    }).add;

    b = Buffer.read(s, "pianomusic.wav"); // link in code description, or use your own...
    s.sync;

    Synth(\wowflutter_2chan ,[
        \bufnum, b.bufnum,
        \out, 0,
        \wobble_rpm, 33,
        \wobble_amp, 0.04,
        \wobble_exp, 11, // best an odd power, higher values produce sharper, smaller peak
        \flutter_amp, 0.02,
        \flutter_fixedfreq, 6,
        \flutter_variationfreq, 2
    ]);
});
)
raw 1110 chars (focus & ctrl+a+c to copy)
reception
comments
jaseknighter user 15 Apr'21 11:55

Hihii! I would like to use this lovely code in a script I'm updating for the monome norns sound computer: https://llllllll.co/t/40261

Assuming you are ok with me using your code, would you please let me know how you would like to be credited? For some reason, just saying "thanks to user 56228375 for the awesome code!" seems a bit impersonal.

Thanks!

56228375 user 18 Apr'21 17:38

you can attribute "Stefaan Himpe"... thanks :)