(
fork { loop {
	Ndef(\ae, {
		var gen = { |...par| [LFNoise2,LFNoise0,LFBrownNoise2,LFBrownNoise0,SinOsc,LFPar].choose.kr(*par) };
		var sig = Median.ar(6, [LFCub,LFSaw,LFPulse].choose.ar(
			LFSaw.kr([8,10]).exprange(40,gen.([1/11,1/9]).exprange(300,600)) 
			* gen.([1/10,1/11]).range(1,3)
		).perform(
			[\ring2,\ring1,\sqrdif].choose,
			VarSaw.ar(
				LFTri.kr([9,11]).exprange(80,gen.([1/10,1/11]).exprange(1200,6200)) 
				* gen.([1/10,1/11]).range(0.3,2),
				0, gen.([1/9,1/8]).range(0.1,0.9)
			)
		))
		* Decay.kr(
			Impulse.kr(
				[2,3] * gen.([1/5,1/6]).exprange(1/2,4), 
				mul: gen.(1).range(0.7,1)
			)
			+ Dust.kr([4,5] / 2 * gen.([1/5,1/6]).exprange(1,4), gen.(1).range(0.2,0.5)), 
			{ gen.(1/5.rrand(10)).range(0.1.rrand(0.2),0.3.rrand(0.5)) } ! 2
		);
		Limiter.ar(
			GVerb.ar(
				Rotate2.ar(sig[0],sig[1], gen.(1)) 
				* LFGauss.kr([1/10,1/11], { gen.(1/9).range(0.15,0.3) } ! 2)
				+ BPF.ar(
					WhiteNoise.ar(EnvGen.kr(Env.perc.circle, 1, gen.([1/3,1/4]).range(0.2, 0.45), 0, gen.([1/4,1/5]).exprange(0.1, 0.5))),
					gen.([1/5,1/6]).range(200.rrand(600), 4200),
					gen.([1/5,1/6]).range(0.5,1.5)
				) / 2,
				8.rrand(12),
				drylevel:gen.(1/7).range(0.2,0.8),
			) / 3
			* EnvGen.kr(Env.sine.circle, 1, 0.8, 0.2, gen.([1/8,1/9]).range(0.2, 2))
		);
	}).fadeTime_(0.1.rrand(0.3)).play;
	(30.rrand(50) * TempoClock.default.beatDur).yield;
}}
)