«Those were the times» by 56228375

on 04 Aug'17 07:21 in pmonobrown noise

When this generative song was released in 2342 it immediately rose to the top spot of the intergalactic U2B channel, easily breaking the all time record of 7 trillion immersive experiences in the first millisecond. Critics praised the composer for the extraordinary independence of melody lines, the bass player for her virtuoso finger picking, the artificially intelligent blender for its awesome shredding and the sopranos for their colorful voice, their extraordinary range and masterful display of subtle vibratos. Sheer excitement reportedly caused entire audiences to grow an extra pair of whiskers during the solos. Those were the times.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
(
s.waitForBoot({

	SynthDef(\singer, {
		| out=0, freq=440, amp=0.5, vibrato=6|
		var lfo, lfo2, lfo3, sig;
		lfo = SinOsc.kr(1/5, 0).range(250,1000);
		lfo2 = SinOsc.kr(1/5, 0).range(0.1,0.9);
		lfo3 = SinOsc.kr(vibrato).range(0.3, 1);
		sig = lfo3*RLPF.ar(in:VarSaw.ar(freq:Lag.ar(in:K2A.ar(freq), lagTime:0.3), iphase:0, width:lfo2, mul:amp), freq:lfo, rq:200/lfo);
		Out.ar(out, sig!2);
	}).add;

	s.sync;

	Pdef.defaultQuant_(0);
	Pdef(\bass, Pmono(\default, \dur, Pwhite(0.01, 0.1, inf), \freq, (Pgbrown(1,8,5) * 20).round(10), \amp, Pbrown(0.2,0.6,0.05)));
	Pdef(\computer, Pmono(\default, \dur, Pwhite(0.01, 0.1, inf), \freq, (Pgbrown(1,8,9) * 100).round(20), \amp, Pbrown(0.2,0.6,0.05)));
	Pdef(\soprano, Pmono(\singer, \dur, Pwhite(0.01, 0.1, inf), \freq, Pgbrown(1,8,0.05) * 200, \amp, Pbrown(0.2,0.6,0.05)/5, \vibrato, Pbrown(4,7,0.125)));
	Pdef(\soprano2, Pmono(\singer, \dur, Pwhite(0.01, 0.1, inf), \freq, Pbrown(3,6,0.1) * 100, \amp, Pbrown(0.2,0.6,0.05)/5, \vibrato, Pbrown(3,8,0.125)));

	fork {
		Pdef(\bass).play;
		10.wait;
		Pdef(\computer).play;
		10.wait;
		Pdef(\soprano).play;
		10.wait;
		Pdef(\soprano2).play;
		10.wait;
		Pdef(\computer).stop;
		20.wait;
		Pdef(\bass).stop;
		10.wait;
		Pdef(\soprano).stop;
		Pdef(\soprano2).stop;
		Pdef(\bass).play;
		Pdef(\soprano).play;
		10.wait;
		Pdef(\soprano2).play;
		10.wait;
		Pdef(\computer).play;
		20.wait;
		Pdef(\bass).stop;
		Pdef(\computer).stop;
		Pdef(\soprano).stop;
		Pdef(\soprano2).stop;
	}

});
)
raw 1537 chars (focus & ctrl+a+c to copy)
reception
comments
badnumbersmusic user 08 Aug'17 17:03

God this takes me back.