«Fed Up with Feedback» by codepool

on 27 Apr'17 22:06 in live codingjitlib

Migration from the old SourceForge wiki.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
p = ProxySpace.push(s.boot);
~out.play;
~out = ~f * 0.1;

(
~f = { 
	var u, in, din, a, b;
	a = MouseX.kr;
	b = MouseY.kr;
	in = ~f.ar;
	din = DelayL.ar(in, 0.3, LFNoise1.kr(0.1).range(0,0.3));
	
	u =  SinOsc.ar(LinExp.kr(a, 0, 1, 200, 800), in * [1, 1.01] * (1-a))
		+
		SinOsc.ar(LinExp.kr(b, 0, 1, 100, 900), din * [1.01, 1])
		*
		Decay2.ar(Dust.ar(5), 0.1, 0.5, 1, 0.1);
	RLPF.ar(u, LinExp.kr(LFNoise1.kr(0.1), -1,1, 200, 1000), 0.2);
};
)

~g = { LFPulse.kr(1) * BPF.ar(Pulse.ar(~f.ar * 200 + 200, ~g.ar.reverse + 0.3), 1000, 0.1) * 0.1 };
~g.play;

(
~f = { 
	var u, in, din, a, b;
	a = MouseX.kr;
	b = MouseY.kr;
	in = ~f.ar;
	din = DelayC.ar(in, 0.3, LFNoise1.kr(50 * b).range(0,0.3));
	
	u =  SinOsc.ar(LinExp.kr(a, 0, 1, 200, 800), in * [1, 1.01] * (1-a))
		+
		SinOsc.ar(LinExp.kr(b, 0, 1, 100, 900), din * [1.01, 1]);
	u = u * Decay2.ar(Impulse.ar(130 * din + 8), 0.01, 0.1, 2, 0.03);

	RLPF.ar(u, LinExp.kr(LFNoise1.kr(0.1), -1,1, 200, 1000), 0.2);
};
)

******
/*
authors so far:
jrh
*/
raw 1046 chars (focus & ctrl+a+c to copy)
reception
comments