«Snow» by grirgz

on 23 Jul'16 13:55 in drone
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
(
Ndef(\snow, { arg freq=200, pan=0, amp=0.1, speed=1;
	var sig;
	var size = 20;
	var trig = Impulse.ar({ rrand(1/1,15.0) } ! size * \density.kr(1));
	sig = { WhiteNoise.ar } ! size;
	sig = sig.collect({ arg sig, x;
		var bpfreq = exprand(50.0,16000) * \tone.kr(1);
		var bpfrq = 0.1 * SinOsc.ar(( x+1 ) * 1/153 * speed).exprange(0.1,4) * \blur.kr(1);
		sig = BPF.ar(sig,  bpfreq, bpfrq) * 34;
		sig = BPF.ar(sig,  bpfreq, bpfrq) * 4;
		sig = sig * EnvGen.ar(Env([0,1,0],[0.1,0.8]), trig[x]);
		//sig = sig.fold2( LFNoise0.kr(1/23 * ( x+1 ) * speed).range(0.01,8) ) * 4;
		sig = sig * SinOsc.ar(1/700 * ( x+1 ) * speed).range(0.01,1);
	});
	sig = Pan2.ar(sig, ( { rrand(-1.0,1) } ! size * SinOsc.ar(1/132 * (1..size) * speed).range(0,1) ), amp).mean;
}).play;
);
Ndef(\snow).fadeTime = 16;
Ndef(\snow).edit;
raw 826 chars (focus & ctrl+a+c to copy)
reception
comments
g_montel user 20 Feb'19 08:17

Love it !!