«vagabond kicks» by vividsnow

on 03 Apr'13 08:15 in sketchexperimentalkick
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
(
{
	var base_freq = LFNoise2.kr(1!2).exprange(35,60);
	Pan2.ar(
		SinOsc.ar( 
			EnvGen.ar(
				Env(
					[ 
						base_freq,
						LFNoise2.kr(1/2!2).exprange(400,6500),
						LFNoise2.kr(1/2!2).exprange(35,125),
						base_freq
					],
					[
						LFNoise2.kr(1/2!2).exprange(0.001,0.008),
						LFNoise2.kr(1/2!2).exprange(0.008,0.13),
						LFNoise2.kr(1/2!2).exprange(0.01,0.5)
					], 
					[
						LFNoise2.kr(1/4!2).exprange(1/5,5), 
						LFNoise2.kr(1/4!2).range(-19,-6), 
						LFNoise2.kr(1/4!2).range(-5,5)
					]
				).circle
			), 0,
			LFNoise2.kr(LFNoise2.kr(1/20!2).exprange(1/9,9)).range(0.05,1)
			//EaseInBounce.ar(SinOsc.ar(LFNoise2.kr(1/10!2).exprange(1/5,5)).range(0,1))
		),
		LFTri.ar(
			LFNoise2.kr(1/20).exprange(1/10,10), [0,2], 
			SinOsc.kr(LFNoise2.kr(1/10!2).exprange(1/5,5)).range(0.3,1)
		)
	).mean;
}.play
)
raw 880 chars (focus & ctrl+a+c to copy)
reception
comments
grirgz user 03 Apr'13 13:45

very strange sound (and cool :p)

I get a strange error too: exception in GraphDef_Recv: UGen '' not installed. (sc3.5.1)

beryann.parker user 10 Apr'13 02:48

Strange and good sound....the server stops every 5 seconds like if it was clipping....

vividsnow user 11 Apr'13 11:33

thanks! I made it under sc3.6.3 - can run indefinitely )