«winter curves» by vividsnow

on 07 Dec'12 17:19 in sketchwintersnow

seasonal reflections )

log fork json 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
(
fork { loop { 
	Ndef(\winter_curves, {
		var bands = 5.rrand(15) * 2;
		var freqs = Array.exprand(bands.debug('bands'), 20, 18000);
		Pan2.ar(
			SinOsc.ar(
				freqs, 
				Array.rand(bands, 0, pi),
				AmpCompA.kr(freqs, freqs.sort.first)
			).perform(0.5.coin.if(\tanh,\value).debug('kind')),
			FSinOsc.kr(
				Array.exprand(bands, 0.01, 15),
				Array.rand(bands, 0, pi),
			),
			bands.reciprocal
			* LFGauss.kr(SinOsc.kr(Array.rand(bands, 0.05, 0.1)).range(1,10), 0.3)
			* FSinOsc.kr(
				Array.exprand(bands, 0.1, 15),
				0.3
			).range(0,1)
		).sum
		* SelectX.kr(
			FSinOsc.kr(Array.exprand(bands, 0.1, 15)).range(0,1),
			[
				EnvGen.kr(
					Env.perc(
						FSinOsc.kr(1/16).range(0.01,0.1),
						FSinOsc.kr(1/8).range(0.25,0.3)
					).blend(
						Env.sine( // 1/4
							FSinOsc.kr(Array.exprand(bands, 0.1, 15)).range(0.05,2)
						).blend(
							Env.sine(1/4),
							FSinOsc.kr(Array.exprand(bands, 0.1, 15)).range(0.05,2).mean
						),
						FSinOsc.kr(Array.exprand(bands, 0.1, 15)).range(0,1)
					).circle,
					1, 0.8, 
					FSinOsc.kr(freqs.linlin(20,18000,0.1,20)).range(0, 0.2).mean
				),
				1
			]
		).clump(2).mean
	}).fadeTime_(0.5.rrand(2.5)).play;
	8.rrand(30).debug('len').wait;
} }
)
raw 1272 chars (focus & ctrl+a+c to copy)
reception
wobbly twinkles
comments
grirgz ↪ user 07 Dec'12 18:26

I get an error when running the code: EnvGen arg: '125' has bad input: nil (the arg number change at each evaluation)

Schemawound ↪ user 07 Dec'12 18:40

Very nice!

Robert van Heumen ↪ user 06 Feb'13 21:35

I get an error when running: • ERROR: Parse error in file 'selected text' line 29 char 4: )•,

vividsnow ↪ user 20 Feb'13 02:46

hmm, maybe it works only in sc3.6

g_montel ↪ user 17 Jun'19 23:26

loving it