«Jazz Arpeggios» by Bjorn Westergard
on 10 Aug'11 03:46 inA synthdef and simple pbind to play some (pretty repetitive) bebop-ish arpeggios. The conjunction reminds me a bit of James Blake.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17
SynthDef(\pluck, {|freq = 440, dur = 1|
var klang,note;
dur = dur * 2;
note = freq.cpsmidi;
note = note + (LFNoise2.ar(20).range(-1,1) * (1/8));
klang = SinOsc.ar((note * [1,1.002]).midicps, phase: VarSaw.ar(note.midicps, width: Line.ar(1,0.2,dur))) * 0.3;
klang = klang * XLine.ar(1,1/10000,dur,doneAction:2);
Out.ar(0, klang);
}).store;
Pbind(
\instrument, \pluck,
\degree, Pn(Pseries(0, Pwrand([Pwhite(-3,3,inf).round(1),1],[32,1],inf), 4),inf)-1 + [0,2,-1,-14],
\dur, Pseq([4, [5,2,1]].convertRhythm / 2, inf),
\strum, Pwhite(0,1/8,inf),
\octave, [5,6]
).play;
descendants
full graph
«Daniel» by anonymous (private)
«jvieyvn» by anonymous (private)
«tuododuq» by anonymous (private)
«Re: Jazz Arpeggios» by brussli1 (private)
reception
Nice, but ... I'm on Mac ... When I execute the code, after a minute or so the cpu goes to 100% :|
Huh. How many synths are running at that point?
a number between 136 and 150
I can only guess that for whatever reasons synths aren't being freed by the XLine envelope. Change it to: XLine.ar(1,1/100,dur,doneAction:2); and see if that fixes it. For what it's worth I don't see that behavior under Ubuntu.
I solved using kr method of XLine: XLine.kr(1,1/10000,dur,doneAction:2) but I really don't know why it works ...
Note: I use Version 3.4.3 (Revision 102c1f92b2) on Mac
( I tried using 1/100 instead of 1/10000 but it didn't work )
on my Mac it's ok and good!! but i had to add the () for the evaluation (if not doesn' t work):
here -->( Pbind( \instrument, \pluck, \degree, Pn(Pseries(0, Pwrand([Pwhite(-3,3,inf).round(1),1],[32,1],inf), 4),inf)-1 + [0,2,-1,-14], \dur, Pseq([4, [5,2,1]].convertRhythm / 2, inf), \strum, Pwhite(0,1/8,inf), \octave, [5,6] ).play; and here->> )
Beryann
+1 reminds me of James Blake