«guitar feedback» by snappizz

on 11 Aug'18 02:33 in feedbackdroneguitarinstrumentdistortionmetal

\m/

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
// results will vary with blocksize. this is tuned for 64.

(
{
    var snd, string, delay;
    string = { |freq|
        var delay;
        delay = freq.reciprocal;
        Pluck.ar(SinOsc.ar(Line.ar(1000, 50, 0.01)) * Env.perc(0.001, 0.01).ar, Impulse.ar(0), delay, delay, 5, 0.5)
    };
    snd = string.(100) + string.(150) + string.(200);
    snd = snd + (HPF.ar(LocalIn.ar(1), 3000) * -50.dbamp);
    snd = (snd * 32.dbamp).tanh;
    snd = RLPF.ar(snd, 3000, 0.5);
    snd = (snd * 32.dbamp).tanh;
    snd = RLPF.ar(snd, 500, 0.5);
    snd = (snd * 32.dbamp).tanh;
    snd = BHiShelf.ar(snd, 3200, 1, -3.0);
    snd = LeakDC.ar(snd);
    LocalOut.ar(snd);
    snd = DelayC.ar(snd, 0.1, SinOsc.kr(2, [0, 1pi]).range(0, 1e-4));
    // uncomment for reverb 3.10
    // snd = snd + (NHHall.ar(snd, 1) * -5.dbamp);
    snd * -20.dbamp;
}.scope(fadeTime: 0);
)
raw 885 chars (focus & ctrl+a+c to copy)
reception
comments
ab2 user 08 Dec'21 22:47

great sound!! Would you possibly mid to explain your mix of the SC-UGens a bit more? I would like to generate/have a stooges sounding eguitar synth that is possibly capable of strumming the G,F# and E of "I Wanna be your dog" somehow. Thanks for some more insight.