Fork Code: Fed Up with Feedback

name

code content

p = ProxySpace.push(s.boot);
~out.play;
~out = ~f * 0.1;

(
~f = { 
	var u, in, din, a, b;
	a = MouseX.kr;
	b = MouseY.kr;
	in = ~f.ar;
	din = DelayL.ar(in, 0.3, LFNoise1.kr(0.1).range(0,0.3));
	
	u =  SinOsc.ar(LinExp.kr(a, 0, 1, 200, 800), in * [1, 1.01] * (1-a))
		+
		SinOsc.ar(LinExp.kr(b, 0, 1, 100, 900), din * [1.01, 1])
		*
		Decay2.ar(Dust.ar(5), 0.1, 0.5, 1, 0.1);
	RLPF.ar(u, LinExp.kr(LFNoise1.kr(0.1), -1,1, 200, 1000), 0.2);
};
)

~g = { LFPulse.kr(1) * BPF.ar(Pulse.ar(~f.ar * 200 + 200, ~g.ar.reverse + 0.3), 1000, 0.1) * 0.1 };
~g.play;

(
~f = { 
	var u, in, din, a, b;
	a = MouseX.kr;
	b = MouseY.kr;
	in = ~f.ar;
	din = DelayC.ar(in, 0.3, LFNoise1.kr(50 * b).range(0,0.3));
	
	u =  SinOsc.ar(LinExp.kr(a, 0, 1, 200, 800), in * [1, 1.01] * (1-a))
		+
		SinOsc.ar(LinExp.kr(b, 0, 1, 100, 900), din * [1.01, 1]);
	u = u * Decay2.ar(Impulse.ar(130 * din + 8), 0.01, 0.1, 2, 0.03);

	RLPF.ar(u, LinExp.kr(LFNoise1.kr(0.1), -1,1, 200, 1000), 0.2);
};
)

******
/*
authors so far:
jrh
*/

code description use markdown for formating

category tags comma separated, i.g. "wild, siren" (do not enter default SC class names, please)

ancestor(s) comma separated identificators, i.g. "1-C,1-1,1-4M,1-x"

Private? the code will be accessible by direct url and not visible in public activity

comment of change