«balungan» by tedthetrumpet

on 14 Jul'16 12:23 in slow

An improvisation on Formant, also using JPverb (from DEINDUGens) and Decimator (from DistortionUGens). 'Balungan' is the name given to the central, skeletal melody that underlies a Javanese gamelan piece: actually, this is not very gamelan-like at all, although the stately pace and occasional gong-like notes put me in that frame of mind.

log fork json 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
t = TempoClock(140/60/32)

(
SynthDef(\bform, { |out = 0, freq = (60.midicps), formfreq = 70, bwfreq = 200, gate = 1, amp = 0.1|
	var env = EnvGen.kr(Env.adsr(releaseTime:0.5, decayTime:0.1), gate, doneAction:2);
	var sig = Formant.ar(freq * ((-1..1)/500 + 1), formfreq * env.range(0.01,2), bwfreq);
	sig = sig * env;
	Out.ar(out, Splay.ar(sig) * amp)
}).add
)
~mbus2 = Bus.audio(s, 2)

Ndef(\l, {LFNoise1.kr(t.tempo)})
Ndef(\m2).put(0, { InFeedback.ar(~mbus2, 2)}).play
Ndef(\m2).put(1, \filter -> { |i| Decimator.ar(i, Ndef(\l).kr.range(1000,4000), bits:17)})
Ndef(\m2).put(2, \filter -> { |i| JPverb.ar(i, t60:5)}).set(\wet1, 0.3)

Pdef(\f, Pmono(\bform, \freq, 110/2, \formfreq, Pfunc({80.rrand(440)}), \dur, 1/4, \bwfreq, 60, \out, ~mbus2))

Pdef(\f).play(t)

Pdef(\f).stop
raw 799 chars (focus & ctrl+a+c to copy)
reception
comments
tedthetrumpet ↪ user 14 Jul'16 12:33

https://soundcloud.com/tedthetrumpet/balungan