Fork Code: Example of morphing (interpolating) between two Signals/Wavetables

name

code content

(
// Set things up, and start the Synth
s.waitForBoot {
	SynthDef(\oscplayer,{ arg out = 0, bufnum;
		var signal;
		signal = Osc.ar(bufnum, MouseX.kr(60, 300));
		Out.ar(out, signal ! 2)
	}).add;

	z = { Env([0] ++ rrand(-0.5, 0.5!5) ++ 0, [0.1, 0.2, 0.05, 0.3, 0.4, 0.1].scramble, \sin).asSignal(512) };
	a = z ! 2;
	// a[0] is the start waveform, a[1] is the target to morph to...
	a.plot;

	c = a[0].asWavetable;
	b.free; b = Buffer.alloc(s, c.size);  // 1024: twice the size of the 512-element signal!
	s.sync;
	b.setn(0, c);

	x = Synth(\oscplayer, [\bufnum, b]);
};
)

(
// Do interpolation from one wave to another
fork {
	var fadeTime = 5; // seconds
	var stepSize = 0.025; // seconds
	var numSteps = fadeTime / stepSize;
	"Fading...".postln;
	numSteps.do { arg i;
		var interp = i / (numSteps - 1);
		var interpSignal = a[0] * (1 - interp) + (a[1] * interp);
		b.setn(0, interpSignal.asWavetable);
		(fadeTime/numSteps).wait;
	};
	"...done!".postln;
};
)

(
// Generate a new target buffer, then run the fork above again to morph to new wave!
a[0] = a[1];
a[1] = z.value;
a.plot;
)

x.free; b.free;

code description use markdown for formating

category tags comma separated, i.g. "wild, siren" (do not enter default SC class names, please)

ancestor(s) comma separated identificators, i.g. "1-C,1-1,1-4M,1-x"

Private? the code will be accessible by direct url and not visible in public activity

comment of change