Fork Code: Chariots of Fire with the \default Synth

name

code content

/*********************************
Chariots of Fire by Vangelis (Default Synth Mock-Up)
Once I started a Pbind with the default synth and got stuck
in a lower octave on one note. This reminds me every time of chariots of fire.
So I decided to give it a go and at least try to reconstruct the beginning.

If someone else wants to complement, make the other parts or write it differently, feel free to fork :)
I just wanted to get this out of my head.
-rukano
**********************************/

TempoClock.default.tempo = 65/60;

~bass = Pbind(*[
	root:1,
	octave:[3,4],
	dur:Pn(1/4, 17*16),
	legato:Pwhite(1.5, 2.0),
	amp:Pwhite(0.1,0.12)
]);

~lead = Pbind(*[
	root:1,
	octave:5,
	degree:Pseq([0,4,\r], 4),
	dur:Pseq([1,4,3], inf),
	legato:1,
	amp:Pwhite(0.1,0.12)
]);

~melody = Pbind(*[
	root:1,
	octave:5,
	degree:Pseq([0,3,4,5,4,2, 0,3,4,5,4, 0,3,4,5,4,2, 2,3,2,0,0], 2),
	dur:Pseq([1,1,1,1,3,5, 1,1,1,1,8, 1,1,1,1,3,5, 1,1,1,1,8]/3, inf),
	amp:Pwhite(0.1,0.12)
]);

Ptpar([0, ~bass, 3, ~lead, 34-(1/3), ~melody]).play;

code description use markdown for formating

category tags comma separated, i.g. "wild, siren" (do not enter default SC class names, please)

ancestor(s) comma separated identificators, i.g. "1-C,1-1,1-4M,1-x"

Private? the code will be accessible by direct url and not visible in public activity

comment of change