Fork Code: Pebble Beach

name

code content

(
// the memory allocation for the server needs to be increased from the default of 8192
// or you'll see the following error:
// exception in real time: alloc failed, increase server's memory allocation (e.g. via ServerOptions)

o = ServerOptions.new;
o.memSize_(16000);
Server.default.options_(o);

Server.default.waitForBoot({
{
arg lo = 800, hi = 1900;
var dust, output, dustSpeed, triSpeed, background, foreground;

background = BrownNoise.ar(0.06) * LFNoise0.kr(34).lag(1.4).range(0.0, 1.0);
background = background + 

Mix.fill(
	20,
	{
	|i|
	BPF.ar(PinkNoise.ar(0.4), LFNoise0.kr(21.8).lag(0.7).range(3100, 4900) * (0.4 + (i * 0.07)), 0.1)
	* LFNoise1.kr(5.227).lag(5.374).range(0.0, 1.0);
	}
) * 0.6;

triSpeed = SinOsc.kr(0.17).range(0.122, 0.24);
dustSpeed = LFTri.kr(triSpeed).exprange(1, 700) * LFTri.kr(triSpeed).exprange(1, 0.2);

foreground = Mix.fill(
	50, 
	{
	var thisOut;
	
	dust = Dust.ar(dustSpeed * rrand(0.8, 1.2), 50);
	lo = SinOsc.kr(2.2).exprange(800, 900);
	hi = SinOsc.kr(5.228).exprange(2600, 2900);
	thisOut = Resonz.ar(dust, TRand.ar(lo, hi, dust) * Saw.kr(triSpeed).range(2, 0.5).lag(0.6, 2.8), TRand.ar(0.03, 0.08, dust));
	thisOut + CombL.ar( thisOut, 0.8, rrand(0.2, 0.8), [-4, 4].choose);
	}
) * 0.2;

output = foreground + background * Line.kr(0.0, 1.0, 1.2);

output ! 2
}.play;
});

)

code description use markdown for formating

category tags comma separated, i.g. "wild, siren" (do not enter default SC class names, please)

ancestor(s) comma separated identificators, i.g. "1-C,1-1,1-4M,1-x"

Private? the code will be accessible by direct url and not visible in public activity

comment of change