«klee» by redFrik

on 13 Nov'11 07:42 in sequencing

i've also written a pattern class Pklee http://fredrikolofsson.com/f0blog/?q=node/467

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
(
SynthDef(\klee8, {|freq= 400, rate= 0.5,
		list= #[0, 0, 0, 0, 0, 0, 0, 0],
		mul= #[0, 0, 0, 0, 0, 0, 0, 0]|
	var i= LFSaw.kr(rate, 1, 0.5, 0.5)*list.size;
	var sum= (mul*Select.kr(i+(0..list.size-1)%list.size, list)).sum;
	var src= SinOsc.ar(freq+sum, 0, Decay2.kr(Impulse.kr(list.size*rate), 0.01, 0.1, 0.5));
	Out.ar(0, Pan2.ar(Mix(src)));
}).add;
)
a= Synth(\klee8)
a.set(\list, #[4, 0, 0, 2, 0, 0, 0, 0]*100)	//set the values
a.set(\mul, #[1, 0, 0, 0, 0, 0, 0, 0])		//activate 1 read head
a.set(\mul, #[1, 1, 0, 0, 0, 0, 0, 0])		//activate 2 read heads
a.set(\mul, #[1, 1, 1, 0, 0, 0, 0, 0])
a.set(\mul, #[1, 1, 1, 1, 0, 0, 0, 0])

a.set(\mul, #[1, 0.5, 0.25, 0, 0, 0, 0, 0])
a.set(\list, #[4, 0, -4, 2, 0, 0, 0, 0]*100)
a.set(\freq, 500)
a.set(\rate, 1.5)
a.free


(
SynthDef(\klee16, {|freq= 400, rate= 0.5,
		list= #[0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0],
		mul= #[0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0]|
	var i= LFSaw.kr(rate, 1, 0.5, 0.5)*list.size;
	var sum= (mul*Select.kr(i+(0..list.size-1)%list.size, list)).sum;
	var src= SinOsc.ar(freq+sum, 0, Decay2.kr(Impulse.kr(list.size*rate), 0.01, 0.1, 0.5));
	Out.ar(0, Pan2.ar(Mix(src)));
}).add;
)
a= Synth(\klee16)
a.set(\list, #[4, 0, 0, 2, 0, 0, 0, 0, 3, 0, 0, 2, 0, 0, 0, 0]*100)	//set the values
a.set(\mul, #[1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0])		//activate 1 read head
a.set(\mul, #[1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0])		//activate 2 read heads
a.set(\mul, #[1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0.25, 0, 0, 0, 0, 0])
a.set(\list, #[4, 0, -4, 2, 0, 0, 0, 0, 3, 0, -3, 2, 0, 0, 0, 0]*100)
a.set(\freq, 500)
a.set(\rate, 1.5)
a.free
descendants
«Sandra» by anonymous (private)
«chtmdnb» by anonymous (private)
«kpxxpag» by anonymous (private)
«Re: klee» by anonymous (private)
full graph
raw 1677 chars (focus & ctrl+a+c to copy)
comments