Fork Code: Happy Birthday Pbind

name

code content

// Happy Birthday with Pbind

// Basic version
// just melody
(
Pbind(
	\midinote, Pseq([
		72, 72, 74, 72, 77, 76,
		72, 72, 74, 72, 79, 77,
		72, 72, 84, 81, 77, 76, 74,
		82, 82, 81, 77, 79, 77
	]),
	\dur, Pseq([
		3/4, 1/4, 1, 1, 1, 2,
		3/4, 1/4, 1, 1, 1, 2,
		3/4, 1/4, 1, 1, 1, 1, 2, // "fermata"
		2/3, 2/3, 1, 1, 4, 6 // triplets etc
	]),
	\amp, 0.5,
	\legato, 1
).play;
)


// ===================
// Fancy version
// One Pbind for melody, another for harmony
(
Pbind(
	\midinote, Pseq([
		/* m1 */ 72, 72,
		/* m2 */ 74, 72, 77,
		/* m3 */ 76, 72, 72,
		/* m4 */ 74, 72, 79,
		/* m5 */ 77, 72, 72,
		/* m6 */ 84, 81, 77,
		/* m7 */ 76, 74, 82, 82,
		/* m8-9 */ 81, 77, 79,
		/* m10-11 */ 77
	]),
	\dur, Pseq([
		/* m1 */ 3/4, 1/4,
		/* m2 */ 1, 1, 1,
		/* m3 */ 2, 3/4, 1/4,
		/* m4 */ 1, 1, 1,
		/* m5 */ 2, 3/4, 1/4,
		/* m6 */ 1, 1, 1,
		/* m7 */ 1, 2, /* <<"fermata" */ 2/3, 2/3,
		/* m8-9 */ 1, 1, 4,
		/* m10-11 */ 6 // last note
	]),
	\amp, 0.4,
	\legato, 1
).play;

// chords (bass clef)
Pbind(
	\midinote, Pseq([
		/* m1 */ \rest,
		/* m2 */ [45, 53, 60], [44, 53, 59],
		/* m3 */ [43, 53, 58],
		/* m4 */ [43, 53, 58], [48, 52, 58],
		/* m5 */ [53, 57, 60, 62],
		/* m6 */ [54, 57, 63], [51, 54, 60], [47, 51, 57, 61],
		/* m7 */ [46, 53, 57, 62], [46, 56, 61], [51, 55, 61],
		/* m8 */ [45, 55, 60], [50, 53, 60], [43, 53, 59],
		/* m9 */ [43, 53, 58],
		/* m10 */[37, 44, 49, 53, 60], [39, 46, 51, 55, 60],
		/* m11 */[39, 48, 53, 55, 57]
		]),
	\dur, Pseq([
		/* m1 */ Rest(1), // one beat rest
		/* m2 */ 2, 1,
		/* m3 */ 3,
		/* m4 */ 2, 1,
		/* m5 */ 3,
		/* m6 */ 1, 1, 1,
		/* m7 */ 3, /*<<"fermata"*/ 2/3, 2/3,
		/* m8-9 */ 1, 1, 1.75, 2.25,
		/* m10 */ 1.5, 1.5,
		/* m11 */ 3
	]),
	\amp, 0.3,
	\legato, 0.9
).play;

// extra embellishments that could not go in the Pbind above
Pbind(
	\midinote, Pseq([
		/* m1 */ \rest,
		/* m2-6 */ \rest, // five bars of rest
		/* m7 */ [67, 72], [65, 72], \rest,
		/* m8-9 */ \rest, \rest, 64, 63, 62
	]),
	\dur, Pseq([
		/* m1 */ Rest(1),
		/* m2-6 */ Rest(15), // five bars of rest (5*3)
		/* m7 */ 1, 2, /* <<"fermata" */ Rest(1),
		/* m8-9 */ Rest(2), Rest(1/3), 2/3, 0.75, 2.25
	]),
	\amp, 0.3,
	\legato, 0.9
).play;
)

// score: https://drive.google.com/file/d/1Ng-Gbhpb09gRQp5WswwwPSjlCl4kSxbx/view?usp=sharing

code description use markdown for formating

category tags comma separated, i.g. "wild, siren" (do not enter default SC class names, please)

ancestor(s) comma separated identificators, i.g. "1-C,1-1,1-4M,1-x"

Private? the code will be accessible by direct url and not visible in public activity

comment of change