«saturated, filtered, reverberated growl» by Luka P.

on 09 Dec'21 07:25 in bassdeepdistortionsaturation

test to use some distortion UGens from Mads' Ported Plugins and ended up with this tootin fatso.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
(
// additional UGens needed:
// AnalogTape, LockhartWavefolder and AnalogVintageDistortion are from
// "ported plugins" https://github.com/madskjeldgaard/portedplugins
// JPverb is in sc3-plugins

Ndef(\test, {
	var snd,freq=50;
	var noise;

	noise = WhiteNoise.ar * LFPulse.kr(freq * [0.5,2],0,0.01).range(0,0.3);
	noise = BPF.ar(noise, LFNoise0.kr([1/5,1/4]).range(1000,8000).lag(1));
	noise = Splay.ar(noise, LFNoise1.ar(1/3).range(-1,1));
	freq = [freq,freq*1.01];
	snd = Pulse.ar(freq);
	snd = snd + Pulse.ar(freq*2.001,LFNoise1.ar(1/3).range(0.01,0.05));
	snd = LeakDC.ar(snd);
	snd = AnalogTape.ar(snd, 0.9, LFNoise1.kr(1/4).range(0,1), 0.5,0,2);
	snd = snd.fold(-0.5,0.9);
	snd = LockhartWavefolder.ar(snd[0] * LFNoise1.kr(1/4).range(1,10), 4) +
	((LockhartWavefolder.ar(snd[1] * LFNoise1.kr(1/4).range(1,10), 4)) * [-1,1]);
	snd = RLPF.ar(snd, LFNoise1.ar(1/4).exprange(200,9000),	LFNoise1.ar(1/3).range(0.1,0.9));
	snd = snd + noise;
	
	snd = AnalogVintageDistortion.ar(snd,0,1, oversample:3);
	snd = LeakDC.ar(snd);
	snd = snd * LFPulse.ar(1/7, width:0.2).lag(0.001);
	snd = JPverb.ar(snd*0.4, 10, 0, 5, low:0.5) + snd;
	snd = Limiter.ar(snd*1, 0.9) * 0.8;

	snd;
}).play
)

// copyright: https://unlicense.org/ //
descendants
«Re: saturated, filtered, reverberated growl» by Luka P. (private)
full graph
raw 1260 chars (focus & ctrl+a+c to copy)
reception
comments
infinite digits user 15 Jan'22 11:43

this is exceptionally good, thanks for sharing!