«Words in a matchbox» by bennigraf

on 04 Oct'12 14:32 in saw synth

http://www.youtube.com/watch?v=9BthuxOp5_s

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
// really early first approach...
(
x.free;
x = {
	var note = Duty.kr(
		6/3.2,
		0, 
		Dseq([45, 45, 48, 41], inf));
	var snd = Saw.ar(note.midicps * SinOsc.kr(7.421).range(0.998, 1.001)) * -12.dbamp!2;
	var trigs = TDuty.kr(
		Dseq([1, 2, 3]/3.2, inf),
		0,
		1);
	var lvls = Duty.kr(
		Dseq([1, 2, 3]/3.2, inf),
		0,
		Dseq([-9, -3, -6], inf));
	snd = snd * lvls.dbamp.lag2(0.1);
	snd = snd * EnvGen.kr(Env.perc(0.3, 0.3), trigs);
	snd = RLPF.ar(snd, EnvGen.kr(Env.perc(0.5, 0.2), trigs) * 3201 + 2311, 0.2);
	snd = LPF.ar(snd, 3000);
	snd = snd * (1 + Latch.ar(WhiteNoise.ar(-8.dbamp), Dust.ar(830))).lag2(0.01);
	snd = snd + LPF.ar(CombC.ar(snd, 0.4, 0.33, 0.52, -4.dbamp), 932);
	snd = FreeVerb2.ar(snd, snd, 0.21, 0.93, 0.9);
	snd * -12.dbamp;
}.play;
)
raw 786 chars (focus & ctrl+a+c to copy)
reception
comments