«Re: winter is coming» by vividsnow

on 16 Sep'11 09:37 in rhythmicsketchcode fork

evolution of this

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
(
{ 
	Limiter.ar(
		Pan2.ar(
			LPF.ar(
				DynKlank.ar(
					`[
						Array.rand(5, 700, 2000), 
						nil, 
						Array.rand(5, 0.2, 5).collect({|freq|
							SinOsc.kr(freq).range(0.1,1)
						})
					], 
					Limiter.ar(
						Dust.ar( SinOsc.kr(1).range(1.5, 4), 0.45) 
						+ 
						Impulse.ar( SinOsc.kr(0.03).range(0.5, 1.2) , 0, 0.9)
					)
				),
				1600,
				0.6
			),
			SinOsc.kr(0.01 + 4.rand, mul:0.5)
		)
		+
		Pan2.ar(
			DynKlank.ar(`[
				Array.rand(5, 700, 2000).collect({ |freq| SinOsc.kr( SinOsc.kr( SinOsc.kr(0.2).range(0, 10) ) ).range(100, freq) }),
				nil, 
				Array.rand(5, 0.3, 1)
			], PinkNoise.ar(0.006) ),
			Lag.kr(TRand.kr(-0.8, 0.8, Pulse.kr(2 + 10.rand)))
		)
	) * LorenzL.ar(MouseX.kr(0, 230), add: 0.5, mul: 0.5)
}.play;
)
raw 799 chars (focus & ctrl+a+c to copy)
reception
comments
beryann.parker user 17 Oct'11 08:39

very good! bravo