// title: etude wild LC
// author: LFSaw
// description:
// end version of the live coding session [etude wild LC](https://lfsaw.bandcamp.com/track/etude-wild-lc), an experimentation around the theme of [sonic wilderness intervention](http://fieldnotes.hybridmatters.net/posts/sonic-wild-code).
// 
// [TAI studio](http://tai-studio.org)
// code:
s.boot;

NdefMixer(s);

Ndef(\a).quant = 1;
Ndef(\a).fadeTime = 10;

Ndef(\a).addSpec(\fFreq, [1000, 20000, \exp]);
Ndef(\a).addSpec(\fRq, [1, 0.0001, \exp]);

(
Ndef(\a, {
	var a = Impulse.ar(([1, 2, 3, 4, 5, 6, 7] / 7).scramble * Line.kr(100, 10, 100), [0] ++ 6.collect{1.0.rand});

	a = RHPF.ar(a, Line.kr(1, {rrand(0.1, 8)}!7, 100) * \fFreq.kr(1000) , \fRq.kr(1)) * LFNoise2.kr(0.4).range(0, 1);

	Splay.ar(a);
})
);


// ------------------------------

Ndef(\b).quant = 1;
Ndef(\b).fadeTime = 8;

Ndef(\b).addSpec(\fFreq, [1000, 20000, \exp]);
Ndef(\b).addSpec(\fRq, [1, 0.0001, \exp]);

(
Ndef(\b, {
	var a = Splay.ar(Impulse.ar(([1, 2, 3, 4, 5, 6, 7] / 7).scramble, [0] ++ 6.collect{1.0.rand}));


	RHPF.ar(a, \fFreq.kr(1000), \fRq.kr(1)) * LFNoise1.kr(0.4).range(0, 1)

})
);

// ------------------------------

Ndef(\fff).fadeTime = 3;
Ndef(\fff, {
	Splay.ar(SinOsc.ar([1100 *0.33, 300, 295, 265, 240] * SinOsc.ar(20, pi).linlin(-1, 1, 0.99, 1.01) * Line.kr(1, 0.1, 100)));
});

}