// title: The Last Thing We Wanna Do
// author: mimetikmusic
// description:
// A little homage to "Come Out" by Steve Reich.
// code:
/* A little homage to "Come Out" by Steve Reich.
   It explores ryhtmic aspects created by phasing, retriggering, and pitch shifting.
   It "detours" the original audio message available here
   http://www.freesound.org/people/ERH/sounds/34667/
   in which a police patrol recites
   "We don't want to scare your children, that's the last thing we wanna do".
   
    */


s.options.memSize=128*1024;
s.boot;

~bus=Bus.audio(s,2);
~buf=Buffer.readChannel(s,"/home/***/Supercollider/sounds/v.wav");

(
SynthDef(\playbuff,{arg in=0,out=0,t_trig=0;
    var i=EnvGen.kr(Env([0,40,0.3,0.4,40,0],[0,60,20,20,30]),gate:1);
    var r=EnvGen.kr(Env([0,10,-0.9,-0.9],[40,20,15]),gate:t_trig,doneAction:2);
    var sig1=PlayBuf.ar(1,in,rate:1+r,trigger:Impulse.kr(i),loop:1);
    var sig2=PlayBuf.ar(1,in,rate:1+r,trigger:Impulse.kr(i+0.01),loop:1);
Out.ar(out,Splay.ar([sig1,sig2],0.5));
};
).add;

SynthDef(\rev,{arg in=0,out=0;
    var sig=In.ar(in,2);
    sig=Compander.ar(sig,sig,0.8,1/3);
    sig=FreeVerb.ar(sig,mix:0.4);
Out.ar(out,sig);
};
).add;
);

Synth(\rev,[\in:~bus]);

fork{
x=Synth(\playbuff,[\out:~bus]);
75.wait;
x.set(\t_trig,1);
};

s.quit;