// title: endless fingers tapping in space
// author: Jascha Narveson
// description:
// an adventure in hi-fi cosmic stereo sound...
// code:
play{
	var taps, seconds, image, width, num, panmod;
	num = 4;
	seconds = 5;
	width = LFSaw.ar(seconds.reciprocal, iphase: 1).range(1, 0);
	panmod = LFNoise1.kr(seconds.reciprocal).range(-0.7, 0.7) * LFSaw.kr(seconds.reciprocal, iphase: 1).range(-1, 1).max(0);
	taps = Array.fill(num, {|i|
		var src, local, imp, pitches, done, pitcharray, dlymod;
		pitcharray = [30 + (i * 4), 33 + (i * 4)].midicps;
		pitches = Duty.ar(seconds, 0, Dseq(pitcharray, inf));
		src = Decay2.ar(Impulse.ar(seconds.reciprocal), 0.01, 1/3/(i+1)) * SinOscFB.ar(pitches, SinOsc.ar(3+i).range(0, 1));
		local = LocalIn.ar(2) + [0, src];
		local = DelayC.ar(local, 0.4, LFSaw.ar(seconds.reciprocal, iphase: 1).range(0.4 * (0.72**i), 0.05));
		LocalOut.ar(local.reverse * 0.8);
		done = local/4;
	});	
	image = taps.sum;
	image = [Pan2.ar(image[0], width.neg + panmod), Pan2.ar(image[1], width + panmod)].sum;
	image = GVerb.ar(image * (1.1 - width), 90, 7, 1) + image;
	Out.ar(0, image);
}