// title: No Quarter pluck synth bass sound
// author: wondersluyter
// description:
// In response to http://sound.stackexchange.com/questions/35138/help-me-make-a-patch-for-this-bass-stab-pluck
// 
// Listen at http://ericsluyter.com/sounds/noquarterbass.mp3
// code:
(
SynthDef(\bass, { |outbus, midinote = 42|
  var freq = midinote.midicps;
  var subfreq = freq / 2;
  
  // Envelopes
  var subenv = EnvGen.kr(Env.perc(0, 1), doneAction:2);
  var env = EnvGen.kr(Env.perc(0, 0.5));
  
  // Component synthesis
  var pluck = Pluck.ar(PinkNoise.ar, 1, 0.2, subfreq.reciprocal) * subenv * 2;
  var tri = VarSaw.ar(freq) * env;
  var sin = SinOsc.ar(freq) * env;
  var sub = (SinOsc.ar([subfreq, subfreq - 2, subfreq + 2]).sum * subenv).tanh;
  var click = RLPF.ar(Impulse.ar(0), [2000, 8000], 1).sum * 1000;
  
  // Initial signal
  var sig = pluck + tri + sub + click;
  
  // Resonant LPFs
  sig = RLPF.ar(sig, XLine.ar(freq * 100, freq * 10, 0.15));
  sig = sig + (MoogFF.ar(sig, freq * 20, 2.5) * 0.1);
  
  // EQ resulting signal
  sig = BPeakEQ.ar(sig, 400, 0.5, -9);
  sig = BPeakEQ.ar(sig, 2000, 0.5, 6);
  sig = BHiShelf.ar(sig, 8000, 1, 3);
  sig = BPeakEQ.ar(sig, 200, 1, 3);
  
  // Apply another envelope to dampen a bit more
  sig = sig * XLine.kr(1, 0.6, 0.1);
  
  // Tanh distortion / limiting
  sig = (sig * 1).tanh;
  
  // Another round of signal coloring, using another RLPF
  // and sine components
  sig = sig + RLPF.ar(sig, XLine.ar(freq * 100, freq * 10, 0.15)) + sin + sub;
  
  // Another round of tanh distortion / limiting
  sig = (sig / 2.3).tanh;
  
  // Another resonant LPF
  sig = MoogFF.ar(sig, XLine.ar(freq*150, freq*30, 0.1), 0.1);
  
  Out.ar(outbus, sig!2);
}).add;
)

(
TempoClock.default.tempo = 1.8;

Pbind(
  \instrument, \bass,
  \midinote, Pseq([
    Pseq([Rest, 42, 42], 3),
    Pseq([Rest, 42, 42, 42]),
    Pseq([Rest, 42, 42], 3),
    Pseq([Rest, 45, 45, 42])
  ], inf),
  \dur, Pseq([
    Pseq([0.75, 0.75, 0.5], 3),
    Pseq([0.5, 0.25, 0.75, 0.5])
  ], inf)
).play
)