// title: Karlambience
// author: josecaos
// description:
// LIttle acidAmbient piece made with Ndef.
// code:
//written by @joseCao5 //julio2013
//www.soundcloud.com/josecaos
//"Karlambience"
//supercollider
s.boot;
s.quit;
s.scope;
////
//evalua out primero
(
~out=Ndef(\fx,{
	var sen1,sen2;
    		Out.ar(0,Compander.ar([sen1=In.ar(20),sen2=In.ar(22)],[sen1,sen2],
				0.5,0.47,0.11,clampTime:0.01,relaxTime:0.2))
}
);
//
~out.play  
//
)
////despues koala+panda juntos
(
(
~pand=Ndef(\panda,{
	var nota=TChoose.kr(Impulse.kr(0.5),[36,48,51,56,60,64,67,71,74]-1/* -1 para transponer tonalidad a B*/);
    Out.ar(20,
	Pan2.ar(
	  FreeVerb.ar(
		BPF.ar(
			LFTri.ar(nota.midicps,0,0.5)+Pulse.ar(nota.midicps+7,0,0.4)
			,Phasor.kr(Impulse.kr(0.0125),0.5,nota,nota*10,0.25),0.2)
			,0.98,0.75,0.01),
		[1, -0.9]))
}
).play.lag(0.050);
);
//
(
~koar=Ndef(\koala,{
	var nota=TChoose.kr(Impulse.kr(1),[36,48,51,56,60,64,67,71,74].scramble-1*1.16);
    Out.ar(22,
	Pan2.ar(
	  FreeVerb.ar(
		BPF.ar(
			LFTri.ar(nota.midicps-12,0,0.2)+Pulse.ar(nota.midicps+12,0,0.09)
			,Phasor.kr(Impulse.kr(0.5),0.5,nota,nota*12,0.25),0.2)
			,0.98,0.75,0.01),
		[1, -0.9]))
}
).play;
);
)
////al final ritmos y atmosfera
(
//cabia las divisiones para modificar el tiempo del sinte
//cambia los valores de: windowSize:pitchshift, modfreq del kick(rate/2,2,[[1.5,0.375],[1.5,0.375]])
//cambiar los segundos del fade in/out 
~cielo=Ndef(\noche,{
	var krate=Demand.kr(Impulse.kr(1/16),0,Drand([0.5,1,2,3,4]*2,inf));
	var brate=Demand.kr(Impulse.kr(1/8),0,Dxrand([0.125,0.125,0.25,0.5],inf));
	var mult=Demand.kr(Impulse.kr(krate/12),0,Dxrand([100,200,300,400,500,600,700,800,1200,1400,1600],inf));
	var rate=Demand.kr(Impulse.kr(1/8),0,Dxrand([0.5,1,1.75,2,2.35,3],inf));
	var sig,sog,kick,sn,hh;
	sig=Blip.ar(Pulse.ar(Pulse.ar(brate,0.5,60,60),0.5,120,250),16,0.15)!2;
	sig=BPF.ar(sig,rate*mult,0.15);
	sig=Limiter.ar(GVerb.ar(sig,12,brate/0.9,0.1,mul:0.35),0.2);
	sog=PitchShift.ar(Limiter.ar(sig,0.5),0.9,rate,mul: 0.85);
	kick=HPF.ar(LFTri.ar(Pulse.ar([[1.5,0.375],[1.5,0.375]],0.5,60,68),0,1),120,0.55);
	sn=BPF.ar(LFNoise0.kr(krate*2)*PinkNoise.ar(Pulse.kr(rate*2,0.5,0.001,0.015)),8000,0.25,mul:0.5);
	hh=GVerb.ar(BPF.ar(LFNoise0.kr(4)*WhiteNoise.ar(0.015),12000,0.5),1,4,0.1,mul:0.35);
	Out.ar(0,
		Limiter.ar(
                     Compander.ar([sig,sog]+kick+sn+hh,[sig,sog],
			0.7,0.69,0.5,clampTime:0.52,relaxTime:0.05),
		Line.kr(0,0.05,60/*0.001*/))); //fade out/in;time 60<->0.001//cambios rapidos
})
);
////libera las variables
~cielo.clear;   
~cielo.free;
~koar.free;
~pand.free;
//record 
s.record;
s.stopRecording; 
//      
s.makeWindow;