// title: blaplop
// author: grirgz
// description:

// code:
(
SynthDef(\bla, { arg out=0, amp=0.1, gate=1, pan=0, freq=200;
    var sig;
    var tab;
    tab = \tab.kr(1 ! 15);
    sig = LFSaw.ar(freq * tab.abs);
    sig = sig.sum;
    sig = RLPF.ar(sig, Rand(10,freq*2) + 100 * SinOsc.ar(tab.abs).range(0.01,Rand(2,7)));
    sig = sig.sum;
    sig = sig / 100;
    sig = sig.tanh;
    sig = sig * EnvGen.ar(Env.adsr(0.01,0.1,0.8,0.1+ExpRand(0.001,0.2)),gate,doneAction:2);
    sig = Pan2.ar(sig, pan, amp);
    Out.ar(out, sig);
}).add;
)

(
Pdef(\plop, Pbind(
    \instrument, \bla,
    \degree, Pstep(Pseq([
        Pseq([0,2,4],4),
        Pseq([0,12,6],4),
        Pseq([0,12,6]+7,1),
    ],inf), 1),
    \octave, 3,
    \tab, Pfunc {
        var tab;
        [
            //tab = { arg n; (n + 1.asFloat.rand + 1).tanh / (n.rand+1) } ! 15;
            tab = { arg n; (n + 2.asFloat.rand + 1) / (n+1) } ! 15;
            tab.postln;
        ]
    },
    \dur, PdurStutter( Prand([1,2,4],inf), Pseq([1,2,3]/2,inf)),
    \amp, 0.4
)).play;
);